Findメソッドでの検索の方法とコード組み立てのコツ

Sub Findメソッド1()

Dim DataRange As Range
Dim PicRange As Range
Dim Arow As Long, sKa As Variant

'Arowはデータ表の行数を表します。
Arow = Cells(6, 2).CurrentRegion.Rows.Count

'データレンジを雑誌名列にセットします。
Set DataRange = Range(Range("G6"), Range("G" & Arow + 5))

'検索値の入力
sKa = Range("L1").Value

'エラーストップを無視するコード
On Error Resume Next

'データレンジから検索値を調べて、PicRangeにセットします。
Set PicRange = DataRange.Find(sKa, LookIn:=xlValues, LookAt:=xlWhole)

Range("L2") = Cells(PicRange.Row, 9).Value
Range("L3") = Cells(PicRange.Row, 6).Value

'エラー無視を解除する
On Error GoTo 0

End Sub

Sub Findメソッド2()

Dim DataRange As Range
Dim PicRange As Range
Dim PicAdd As String
Dim RePRange As Range
Dim Arow As Long, sKb As Variant
Dim n As Long

'Arowはデータ表の行数を表します。
Arow = Cells(6, 2).CurrentRegion.Rows.Count

'データレンジを雑誌名列にセットします。
Set DataRange = Range(Range("F6"), Range("F" & Arow + 5))

'検索値の入力
sKb = Range("K31").Value

'データレンジから検索値を調べて、PicRangeにセットします。
Set PicRange = DataRange.Find(sKb, LookIn:=xlValues, LookAt:=xlWhole)

'Offsetの移動値の初期設定
n = 0

'検索値に合致する値が無いこととが無い（ある）時
If Not PicRange Is Nothing Then

'見つかったセルのアドレスを「PicAdd」に格納する
    PicAdd = PicRange.Address

'次の検索を行うため作業をループする
    Do

'見つかったセルから必要データのあるセルに移動しその値を抽出する
        Range("L31").Offset(n) = Cells(PicRange.Row, 7).Value
        Range("M31").Offset(n) = Cells(PicRange.Row, 9).Value

'FindNextメソッドで次を検索する
        Set PicRange = DataRange.FindNext(PicRange)

'新たに見つかったセルのアドレスが、最初のセルのアドレスに一致した場合
        If PicRange.Address = PicAdd Then Exit Do

'Offsetの移動値を1つ増やす
        n = n + 1
    Loop
End If

End Sub

Sub Findメソッド3()

Dim DataRange As Range
Dim PicRange As Range
Dim PicAdd As String
Dim RePRange As Range
Dim Arow As Long, sKc As Variant
Dim n As Long

'Arowはデータ表の行数を表します。
Arow = Cells(6, 2).CurrentRegion.Rows.Count

'データレンジをジャンル列にセットします。
Set DataRange = Range(Range("D6"), Range("D" & Arow + 5))

'検索値の入力
sKc = Range("K31").Value

'データレンジから検索値を調べて、PicRangeにセットします。
Set PicRange = DataRange.Find(sKc, LookIn:=xlValues, LookAt:=xlPart)

'Offsetの移動値の初期設定
n = 0

'検索値に合致する値が無いこととが無い（ある）時
If Not PicRange Is Nothing Then

'見つかったセルのアドレスを「PicAdd」に格納する
    PicAdd = PicRange.Address

'次の検索を行うため作業をループする
    Do

'見つかったセルから必要データのあるセルに移動しその値を抽出する
        Range("L31").Offset(n) = Cells(PicRange.Row, 7).Value
        Range("M31").Offset(n) = Cells(PicRange.Row, 9).Value

'FindNextメソッドで次を検索する
        Set PicRange = DataRange.FindNext(PicRange)

'新たに見つかったセルのアドレスが、最初のセルのアドレスに一致した場合
        If PicRange.Address = PicAdd Then Exit Do

'Offsetの移動値を1つ増やす
        n = n + 1
    Loop
End If

End Sub