ピンポイントでファイルを完全に削除するマクロ（コピペ可）

エクセルVBAマクロで、ファイルの削除方法についてです。今回はKillステートメントを使用します。
ファイルをピンポイントで完全削除するマクロを紹介します。コピペOKです。

こんにちは、じゅんぱ店長（@junpa33）です。

今回は、ファイルを削除するためのVBAコードについてです。

ファイルの削除のためには「Killステートメント」または「DeleteFile」を利用します。ここでは、コードの可読性の良いKillステートメントを使用することにします。

現在のPCはどれも、ストレージ容量が大きく、その分、不要になったファイルをすぐに廃棄しなくても、保存可能容量的には圧迫されることは無いでしょう。以前はファイル整理（削除）作業でフォルダ単位で ” バッサリ ”をというのがよくありました。

今は、ファイル削除と言えば、ファイル単位で必要限度の削除処理というイメージです。

なので、この記事では削除手法的に、

「その都度、目標のファイルを指定して、そのファイルを削除処理する」

というスタイルのマクロ（VBAコード）の記述方法を紹介したいと思います。

コンテンツ

ファイルの削除を行うKillステートメント

Killステートメントは、記述構文としてはこのようになります。

Killステートメントの構文

Kill ファイルパス

ファイルパスの記述方法については別記事も参考にしてください。

VBA

Sub Killステートメント例示()
        Kill "C:\Users\〇〇〇\Documents\削除対象ファイル\Book3.xlsx"
End Sub

このサンプルコードを実行すると、削除対象フォルダ内のBook3.xlsxが削除されます。

基本的にKillステートメントの使い方はこのようにして実行できます。

ただし、これは ” 基本的に ” であって、実務的にはこれだけでは利用価値がありません。最低限の問題を処理しておく必要があります。

マクロに直接に「削除ファイルのパス」を書くくらいなら、マウスで手動削除した方が速い。「削除ファイルのパス」はその都度変えれるようにしたい。
実務での、ファイルを開いて内容を確認して「不要なら削除」の作業手順の中で削除をしたい。ファイルが開いた状態ではこの「基本的なKillコード」は実行できない。
「やっぱり削除を止めます」を出来るようにしたい。

目次へ戻る

指定したファイルを完全に削除する

例示として、マクロ実行ブックと同じフォルダにある「Book2.xlsx」をピンポイント削除します。

処理前のフォルダ

処理後のフォルダ

指定したファイルを完全に削除するVBAコード

削除コード全体は以下のようになります。

VBA

Sub ファイルの削除1()
    Dim BkName As Variant
    Dim wb As Workbook
    Dim Ans As Integer
'■-----------ファイル名取得部分
        ChDir ThisWorkbook.Path
        BkName = Application.GetOpenFilename(filefilter:= _
            "Excelファイル,*.xls*", Title:="ファイル選択")
'--●---------ファイル名を取得できたとき
        If BkName <> False Then
'--●-▲------指定したファイルが現在開かれた状態かどうか
            For Each wb In Workbooks
                If wb.Name = Dir(BkName) Then
                    MsgBox wb.Name & "が選択されました。" & vbCrLf & _
                    "" & vbCrLf & "このファイルは開かれています。" _
                    & vbCrLf & "" & vbCrLf & "いったん終了させます。", _
                    vbInformation
                    wb.Close False
                    Exit For
                End If
            Next
'--●-▲------指定したファイルが現在開かれた状態かどうかここまで
            Ans = MsgBox(BkName & vbCrLf & "" & vbCrLf & _
                "を本当に削除しますか？", vbYesNo + vbExclamation, _
                "ファイル削除確認")
'--●---------ファイル名を取得できなかったとき
        Else
            MsgBox "キャンセルされました"
            Exit Sub
        End If
'■-----------ファイル名を取得できたかどうか条件分岐ここまで
'◆-----------削除実行
        If Ans = 6 Then
            Kill BkName
            MsgBox "ファイルが完全に削除されました。", vbInformation
        Else
            MsgBox "ファイルの削除を中止しました。", vbInformation
            Exit Sub
        End If
'◆-----------削除実行ここまで
End Sub