合計支給金額決定のための日給合計とマルメ計算のVBAコード。時給の計算その6

コード作成のチェックポイントは

1. 時間外割増と時間マルメの指定が空欄の時の処理
2. 時給計算表が存在するかどうかを調べる
3. 日給計算日数の表示
4. 基準時間の合計時間の計算
5. 休憩時間の合計時間の計算
6. 実労時間の合計時間の計算
7. 時間外時間の合計時間の計算
8. 合計支給金額の計算

になります。

Sub 合計計算()

Dim Sh As Worksheet
Dim res As Boolean
Dim Vs As Long, Vss As Long
Dim Vt As Long, Vtt As Long

Call Module1.設定値代入

'時間外割増率が空欄の時100%とします
If TwCos = "" Then TwCos = 100

'時間マルメが空欄の時は0とします
If TMal = "" Then TMal = 0

'計算するシートが存在するかを調べます
res = False
For Each Sh In Worksheets
    If Sh.Name = EmpName & "時給計算表" Then
        res = True
        Worksheets(EmpName & "時給計算表").Select
        Exit For
    End If
Next

'ない場合はプロシージャーを終了する
    If res = False Then
        MsgBox "まだ何も設定されていません。"
        Exit Sub
    End If

'計算日数合計を表示します
Range("B32") = "日数合計 " & BRow - 2 & "日"

'基準時間の合計時間を計算します
Range("C32") = WorksheetFunction.Sum(Range("C3:C31"))

'休憩時間の合計時間を計算します
Range("F32") = WorksheetFunction.Sum(Range("F3:F31"))

'実労時間の合計時間を計算します
Range("G32") = WorksheetFunction.Sum(Range("G3:G31"))

'時間外時間の合計時間を計算します
Range("H32") = WorksheetFunction.Sum(Range("H3:H31"))

'合計支給金額を計算します
'--------時間外時間が発生しているかどうかで区別します
If Range("H32") > 0 Then

'--------基準時間合計に24と時給を乗じます
    Vss = Range("C32") * 24 * TCos

'---------値を切り上げ（小数点を切り上げ）
    Vs = WorksheetFunction.RoundUp(Vss, 0)

'--------基準時間合計に24と時給と割増率を乗じます
    Vtt = Range("H32") * 24 * TCos * TwCos

'---------値を切り上げ（小数点を切り上げ）
    Vt = WorksheetFunction.RoundUp(Vtt, 0)

Else
    Vss = Range("G32") * TCos

'---------値を切り上げ（小数点を切り上げ）
    Vs = WorksheetFunction.RoundUp(Vss, 0)
    
End If

    Range("I32") = Vs + Vt

'参考金額を表示します
    Range("J32") = Vs
    Range("K32") = Vt

End Sub

時間外割増と時間マルメの指定が空欄の時の処理

時間外割増変数「TwCos」が空欄時のエラー回避のため強制的に「割増なし」

時間マルメ変数「TMal」が空欄時のエラー回避のため強制的に「マルメなし」

に、設定します。

時給計算表が存在するかどうかを調べる

VBAコードの基本的なエラー「インデックスが有効範囲にありません」を防止するためのコードを組み込みます。

日給計算日数の表示

B列のデータ記入行数を数えます。

基準時間の合計時間の計算

「 WorksheetFunction.Sum」関数でC列のセル範囲の合計を計算します。

休憩時間の合計時間の計算

「 WorksheetFunction.Sum」関数でF列のセル範囲の合計を計算します。

実労時間の合計時間の計算

「 WorksheetFunction.Sum」関数でG列のセル範囲の合計を計算します。

時間外時間の合計時間の計算

「 WorksheetFunction.Sum」関数でH列のセル範囲の合計を計算します。

合計支給金額の計算

考え方を分かりやすくするため、時間外時間が発生しているかどうかで条件分岐を行います。

先回紹介した「シリアル値」の考え方を使って計算を行います。

勤務時間と時給金額で日給を計算するVBAコードを作成。時給の計算その5

ここでのチェックポイントです

1. 時間マルメ実労時間について
2. 実労分マルメの「分」を計算
3. 実労分からの差分を計算
4. 実労分マルメ時間を表示する
5. 時間外分マルメの「分」を計算
6. 時間外分からの差分を計算
7. 時間外分マルメ時間を表示する
8. 時間マルメまでの支給額合計を計算
9. 金額マルメで支給金額を決定

Sub マルメ計算()

Dim Sh As Worksheet
Dim res As Boolean
Dim Vxa As Long, Vza As Long
Dim Vxb As Long, Vzb As Long
Dim LVM As Long

Call Module1.設定値代入

'時間外割増率が空欄の時100%とします
If TwCos = "" Then TwCos = 100

'時間マルメが空欄の時は0とします
If TMal = "" Then TMal = 0

'計算するシートが存在するかを調べます
res = False
For Each Sh In Worksheets
    If Sh.Name = EmpName & "時給計算表" Then
        res = True
        Worksheets(EmpName & "時給計算表").Select
        Exit For
    End If
Next

'ない場合はプロシージャーを終了する
    If res = False Then
        MsgBox "まだ何も設定されていません。"
        Exit Sub
    End If

'時間マルメ実労時間について

'------マルメを設定しているとき
If TMal <> 0 Then

'------------マルメの「分」を計算
    Vxa = WorksheetFunction.RoundUp(Minute(Range("G32")) / TMal, 0) * TMal

'------------実労分からの差分を計算
    Vza = Vxa - Minute(Range("G32"))

'------------マルメ時間を表示する
    Range("G34") = DateAdd("n", Vza, Range("G32"))

'時間マルメ時間外時間について

'------------マルメの「分」を計算
    Vxb = WorksheetFunction.RoundUp(Minute(Range("H32")) / TMal, 0) * TMal

'------------時間外分からの差分を計算
    Vzb = Vxb - Minute(Range("H32"))

'------------マルメ時間を表示する
    Range("H34") = DateAdd("n", Vzb, Range("H32"))

'------マルメを設定しないとき
Else
    Range("G34") = Range("G32")
    Range("H34") = Range("H32")
End If

'時間マルメまでの支給額合計を計算
LVM = Range("C32") * 24 * TCos + Range("H34") * 24 * TCos * TwCos

'金額マルメで支給金額を決定

'------切り上げしない
If KMal = 0 Or KMal = "" Then
    Range("F34") = "マルメなし"
    Range("I34") = LVM

'------1円以下を切り上げ
ElseIf KMal = 1 Then
    Range("F34") = "10円単位"

'-------------1桁を小数点以下にする
    Range("I34") = WorksheetFunction.RoundUp(LVM / 10, 0) * 10

'-------10円以下を切り上げ
ElseIf KMal = 2 Then
    Range("F34") = "100円単位"

'-------------2桁を小数点以下にする
    Range("I34") = WorksheetFunction.RoundUp(LVM / 100, 0) * 100

'--------100円以下を切り上げ
ElseIf KMal = 3 Then
    Range("F34") = "1000円単位"

'-------------3桁を小数点以下にする
    Range("I34") = WorksheetFunction.RoundUp(LVM / 1000, 0) * 1000
    
Else
    Range("F34") = "マルメなし"
    Range("I34") = LVM
    
End If

End Sub